Add iOS/macOS MH_FILESET KernelCache View and loader.

This loader is inspired by/based on our dyld_shared_cache loader, following the same design language. It targets primarily the latest kernels, but should support any with the MH_FILESET format.

It allows you to decide which images you would like to map in (the kernel itself included), resulting in targeted analysis when you may only need to load a singular image.

It also supports dropping in compressed KernelCaches, directly from the ipsw.

This is an early solution and we have many more changes and improvements planned. We look forward to your feedback

1 files changed, 79 insertions, 0 deletions

diff --git a/view/kernelcache/api/CMakeLists.txt b/view/kernelcache/api/CMakeLists.txt
new file mode 100644
index 00000000..ae7e454a
--- /dev/null
+++ b/view/kernelcache/api/CMakeLists.txt
@@ -0,0 +1,79 @@
+cmake_minimum_required(VERSION 3.13 FATAL_ERROR)
+
+project(kernelcacheapi)
+file(GLOB BN_MACHO_API_SOURCES *.cpp *.h)
+add_library(kernelcacheapi OBJECT ${BN_MACHO_API_SOURCES})
+
+
+set(COMPILE_DEFS "")
+
+if (HARD_FAIL_MODE)
+        set(COMPILE_DEFS "${COMPILE_DEFS} ABORT_FAILURES;")
+endif()
+
+if (BN_REF_COUNT_DEBUG)
+        set(COMPILE_DEFS "${COMPILE_DEFS} BN_REF_COUNT_DEBUG;")
+endif()
+
+if (SLIDEINFO_DEBUG_TAGS)
+        set(COMPILE_DEFS "${COMPILE_DEFS} SLIDEINFO_DEBUG_TAGS;")
+endif()
+
+if (METADATA_VERSION)
+        set(COMPILE_DEFS "${COMPILE_DEFS} METADATA_VERSION=${METADATA_VERSION};")
+else()
+        message(FATAL_ERROR "No metadata version provided. Fatal.")
+endif()
+
+if (KC_VIEW_NAME)
+        set(COMPILE_DEFS "${COMPILE_DEFS} KC_VIEW_NAME=\"${KC_VIEW_NAME}\";")
+else()
+        message(FATAL_ERROR "No view name provided. Fatal.")
+endif()
+
+target_compile_definitions(kernelcacheapi PRIVATE ${COMPILE_DEFS})
+
+
+function(get_recursive_include_dirs target result)
+        # Initialize an empty list to store include directories
+        set(include_dirs "")
+
+        # Get the include directories of the current target
+        get_target_property(current_target_includes ${target} INTERFACE_INCLUDE_DIRECTORIES)
+        if(current_target_includes)
+                list(APPEND include_dirs ${current_target_includes})
+        endif()
+
+        # Get the libraries that this target links to
+        get_target_property(linked_libraries ${target} INTERFACE_LINK_LIBRARIES)
+        if(linked_libraries)
+                foreach(linked_library IN LISTS linked_libraries)
+                        # Skip plain library names (non-target libraries)
+                        if(TARGET ${linked_library})
+                                # Recursively get include directories from linked libraries
+                                get_recursive_include_dirs(${linked_library} linked_library_includes)
+                                list(APPEND include_dirs ${linked_library_includes})
+                        endif()
+                endforeach()
+        endif()
+
+        # Set the result to the collected include directories
+        set(${result} ${include_dirs} PARENT_SCOPE)
+endfunction()
+
+get_recursive_include_dirs(binaryninjaapi INCLUDES)
+
+target_include_directories(kernelcacheapi
+        PUBLIC ${PROJECT_SOURCE_DIR} ${INCLUDES})
+
+set_target_properties(kernelcacheapi PROPERTIES
+        CXX_STANDARD 17
+        CXX_VISIBILITY_PRESET hidden
+        CXX_STANDARD_REQUIRED ON
+        VISIBILITY_INLINES_HIDDEN ON
+        POSITION_INDEPENDENT_CODE ON
+        ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR}/out)
+
+if (NOT DEMO)
+        add_subdirectory(python)
+endif()
\ No newline at end of file